1//////////////////////////////////////////////////////////////////////////////////////////////
2// LibFile: tripod_mounts.scad
3// Mount plates for tripods. Currently only the Manfrotto RC2 plate.
4// Includes:
5// include <BOSL2/std.scad>
6// include <BOSL2/tripod_mounts.scad>
7// FileGroup: Parts
8// FileSummary: Tripod mount plates: RC2
9//////////////////////////////////////////////////////////////////////////////////////////////
10
11
12// Module: manfrotto_rc2_plate()
13// Usage:
14// manfrotto_rc2_plate([chamfer],[anchor],[orient],[spin]) [ATTACHMENTS];
15// Description:
16// Creates a Manfrotto RC2 quick release mount plate to mount to a tripod. The chamfer argument
17// lets you control whether the model edges are chamfered. By default all edges are chamfered,
18// but you can set it to "bot" to chamfer only the bottom, so that connections to a model larger
19// than the plate doin't have a V-groove at the junction. The plate is 10.5 mm thick.
20// Arguments:
21// chamfer = "none" for no chamfer, "all" for full chamfering, and "bot" or "bottom" for bottom chamfering. Default: "all".
22// Examples:
23// manfrotto_rc2_plate();
24// manfrotto_rc2_plate("bot");
25module manfrotto_rc2_plate(chamfer="all",anchor,orient,spin)
26{
27 chsize=0.5;
28
29 dummy = assert(in_list(chamfer, ["bot","bottom","all","none"]), "chamfer must be \"all\", \"bottom\", \"bot\", or \"none\"");
30 chamf_top = chamfer=="all";
31 chamf_bot = in_list(chamfer, ["bot","bottom","all"]);
32
33 length = 52.5;
34 innerlen=43;
35
36 topwid = 37.4;
37 botwid = 42.4;
38
39 thickness = 10.5;
40
41 flat_height=3;
42 angled_size=5;
43 angled_height = thickness - flat_height*2;
44 angled_width = sqrt(angled_size^2-angled_height^2);
45
46 corner_space = 25;
47 corner_space_ht = 4.5;
48
49 left_top=2;
50
51 pts = turtle([
52 "move",botwid,
53 "left",
54 "move", flat_height,
55 "xymove", [-angled_width, angled_height],
56 "move", flat_height,
57 "left",
58 "move", topwid,
59 "left",
60 "move", left_top,
61 "jump", [0,flat_height]
62 ]);
63
64
65 cutout_len=26;
66
67
68 facet = [
69 back(-left_top,select(pts,-3)),
70 each fwd(1.5,select(pts,-2,-1)),
71 [-10,-left_top+select(pts,-1).y],
72 left(10,back(-flat_height,select(pts,-3)))
73 ];
74
75 attachable(anchor,spin,orient,size=[botwid,length,thickness],size2=[topwid,length],shift=[.64115/2,0]){
76 tag_scope()
77 down(thickness/2)
78 diff()
79 linear_sweep(pts,h=length,convexity=4,orient=FWD,anchor=FWD){
80 tag("remove"){
81 zflip_copy()
82 down(.01)fwd(.01)left(.01)position(LEFT+FRONT+BOT)
83 cuboid([corner_space,(length-innerlen)/2,thickness+.02], chamfer=-chsize,
84 orient=FWD,anchor=TOP+LEFT+FWD,edges=chamf_top?"ALL":TOP);
85 fwd(left_top)position(LEFT+BACK)linear_sweep(h=cutout_len,facet,convexity=4,anchor=RIGHT+BACK);
86 }
87 if (chamf_bot){
88 edge_mask(FRONT+LEFT)chamfer_edge_mask(length,chsize);
89 edge_mask(FRONT+RIGHT)chamfer_edge_mask(length,chsize);
90 edge_mask(FRONT+TOP)chamfer_edge_mask(length,chsize);
91 edge_mask(FRONT+BOT)chamfer_edge_mask(length,chsize);
92 edge_mask(TOP+RIGHT)chamfer_edge_mask(length,chsize);
93 edge_mask(BOT+RIGHT)chamfer_edge_mask(length,chsize);
94 zflip_copy(){
95 right(corner_space)edge_mask(TOP+LEFT) chamfer_edge_mask(length,chsize);
96 down((length-innerlen)/2)edge_mask(TOP+LEFT) chamfer_edge_mask(length,chsize);
97 }
98 }
99 if (chamf_top){
100 edge_mask(BACK+LEFT) chamfer_edge_mask(length,chsize);
101 edge_mask(BACK+RIGHT) chamfer_edge_mask(length,chsize);
102 edge_mask(BACK+TOP) chamfer_edge_mask(length,chsize);
103 edge_mask(BACK+BOT) chamfer_edge_mask(length,chsize);
104 }
105 }
106 children();
107 }
108}